ACDSee 3.1 SR1 美化版

admin

1. ;************************************************************
   
2. ;脚本编写: 蓝色网际
   
3. 
   
4. ;某些使用了 LogSet 指令的脚本需要使用特别版的 makensis.exe 才能通过编译
   
5. ;地址: http://nsis.sourceforge.net/download/specialbuilds/
   
6. 
   
7. ; 定义 DEBUG 时安装完成将弹出安装信息
   
8. ;!define DEBUG
   
9. ;************************************************************
   
10. 
    
11. !ifdef NSIS_MOD_CHS
    
12. Name                 "ACDSee 3.1 SR1 美化版 build ${__MONTH__}${__DAY__}"
    
13. !else
    
14. Name                 "ACDSee 3.1 SR1 美化版"
    
15. !endif
    
16. OutFile              "acdc31sr1.exe"
    
17. SetCompressor        lzma                  
    
18. SpaceTexts           none                  
    
19. ShowInstDetails      show                  
    
20. BrandingText         "$(^NameDA)安装程序 ${__DATE__} "
    
21. UninstallCaption     "$(^NameDA)卸载程序"
    
22. ShowUninstDetails    show
    
23. InstallDir           "$PROGRAMFILES\ACDSee"
    
24. InstallDirRegKey     HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\ACDSee" InstallDir
    
25. 
    
26. ReserveFile          ".\resource\acdsee.ini"
    
27. ReserveFile          ".\resource\gaydata.ini"
    
28. ReserveFile          "${NSISDIR}\Plugins\System.dll"
    
29. 
    
30. !include             "MUI.nsh"
    
31. !include             "StrFunc.nsh"
    
32. !include             "Sections.nsh"
    
33. 
    
34.         !define MUI_ICON ".\resource\ico-inst.ico"
    
35.   !define MUI_UNICON ".\resource\ico-uninst.ico"
    
36.   !define MUI_WELCOMEFINISHPAGE_BITMAP ".\resource\Winz.bmp"
    
37.   !define MUI_COMPONENTSPAGE_CHECKBITMAP ".\resource\acdsee.bmp"
    
38.   !define MUI_HEADERIMAGE
    
39.   !define MUI_HEADERIMAGE_BITMAP ".\resource\Header.bmp"
    
40.   !define MUI_WELCOMEPAGE_TEXT "ACDSee 是目前最流行的数字图象处理软件，它能广泛应用于图片的获取、管理、浏览、优化甚至和他人的分享！使用 ACDSee，你可以从数码相机和扫描仪高效获取图片，并进行便捷的查找、组织和预览。超过 50 种常用多媒体格式被一网打尽！作为最重量级看图软件，它能快速、高质量显示您的图片，再配以内置的音频播放器，我们就可以享用它播放出来的精彩幻灯片了。ACDSee 还能处理如 Mpeg 之类常用的视频文件。此外 ACDSee 是您最得心应手的图片编辑工具，轻松处理数码影像，拥有的功能像去除红眼、剪切图像、锐化、浮雕特效、曝光调整、旋转、镜像等等，还能进行批量处理。"
    
41. 
    
42.   !define MUI_PAGE_CUSTOMFUNCTION_SHOW ChageFONT
    
43.   !insertmacro MUI_PAGE_WELCOME
    
44.   !insertmacro MUI_PAGE_LICENSE ".\resource\License.rtf"
    
45.   Page custom SetCustom
    
46.         !define MUI_PAGE_CUSTOMFUNCTION_PRE ComponentPre
    
47.         !define MUI_PAGE_CUSTOMFUNCTION_SHOW ComponentShow
    
48.   !insertmacro MUI_PAGE_COMPONENTS
    
49.   !insertmacro MUI_PAGE_DIRECTORY
    
50.         !define MUI_PAGE_HEADER_TEXT "文件关联"
    
51.         !define MUI_PAGE_HEADER_SUBTEXT "选择需要关联的文件格式"
    
52.         !define MUI_PAGE_CUSTOMFUNCTION_PRE AsscoiationPre
    
53.         !define MUI_PAGE_CUSTOMFUNCTION_SHOW AsscoiationShow
    
54.   !insertmacro MUI_PAGE_COMPONENTS
    
55.   !insertmacro MUI_PAGE_INSTFILES
    
56.   !define MUI_PAGE_CUSTOMFUNCTION_SHOW ChageFONT
    
57.   !insertmacro MUI_PAGE_FINISH
    
58. 
    
59.   !insertmacro MUI_UNPAGE_CONFIRM
    
60.   !insertmacro MUI_UNPAGE_INSTFILES
    
61.   
    
62.   !insertmacro MUI_LANGUAGE "SimpChinese"
    
63.   ChangeUI IDD_SELCOM ".\resource\acdsee_nodesc.exe"
    
64. 
    
65. ;声明字串操作指令
    
66. ${StrCase} ;小写转大写
    
67. 
    
68. !macro ASSOC EXT ICON
    
69.         Push $0
    
70.         Push $1
    
71.        
    
72.         ${StrCase} $0 '${EXT}' "U"
    
73.        
    
74.         ReadRegStr $1 HKCR ".${EXT}" ""
    
75.         ${If} $1 != "ACDSee.$0"
    
76.                 WriteRegStr HKCR ".${EXT}\UndoClass" "" $1
    
77.                 WriteRegStr HKCR "ACDSee.File" "${EXT}" ""
    
78.         ${ElseIf} $1 != ""
    
79.                 DeleteRegValue HKCR "ACDSee.$0\shell\open\DropTarget" Clsid
    
80.                 DeleteRegValue HKCR "ACDSee.$0\shell\open" MuiVerb
    
81.         ${EndIf}
    
82.        
    
83.   DeleteRegKey HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.${EXT}"
    
84.   WriteRegStr HKCR ".${EXT}" "" "ACDSee.$0"
    
85.   WriteRegStr HKCR "ACDSee.$0" "" "ACDSee $0 图像"
    
86.   WriteRegStr HKCR "ACDSee.$0\DefaultIcon" "" "${ICON}"
    
87.   WriteRegStr HKCR "ACDSee.$0\shell" "" Open
    
88.   WriteRegStr HKCR "ACDSee.$0\shell\Open" "" "用 ACDSee 打开"  
    
89.   WriteRegStr HKCR "ACDSee.$0\shell\Open\Command" "" '"$INSTDIR\ACDSee.exe" /dde'
    
90.   WriteRegStr HKCR "ACDSee.$0\shell\Open\DDEExec" "" '[open("%1")]'
    
91.   WriteRegStr HKCR "ACDSee.$0\shell\Open\DDEExec\Application" "" ACDSee
    
92.   WriteRegStr HKCR "ACDSee.$0\shell\Open\DDEExec\Topic" "" System
    
93.   WriteRegStr HKCR "ACDSee.$0\shell\ACDPrint" "" "用 ACDSee 打印"
    
94.   WriteRegStr HKCR "ACDSee.$0\shell\ACDPrint\Command" "" '"$INSTDIR\ACDSee.exe" /p "%1"'
    
95.        
    
96.         ReadRegStr $1 HKCR "CLSID\{68f32140-2ca3-11d0-acc1-444553540000}" ""
    
97.         StrCmp $1 "" +2
    
98.   WriteRegStr HKCR "ACDSee.$0\shellex\ContextMenuHandlers\PicaView" "" "{68f32140-2ca3-11d0-acc1-444553540000}"
    
99.   
    
100.         DetailPrint "关联文件: .$0"
     
101.        
     
102.         Pop $1
     
103.         Pop $0
     
104. !macroend       
     
105. 
     
106. !macro ASSOC_TYPE EXT TYPE
     
107.         Push $0
     
108.        
     
109.         ReadRegStr $0 HKCR ".${EXT}" ""
     
110.         StrCmp $0 "ACDSee.${TYPE}" +3
     
111.         WriteRegStr HKCR ".${EXT}\UndoClass" "" $0
     
112.         WriteRegStr HKCR "ACDSee.FILE" "${EXT}" ""
     
113.        
     
114.   DeleteRegKey HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.${EXT}"
     
115.   WriteRegStr HKCR ".${EXT}" "" "ACDSee.${TYPE}"
     
116.   
     
117.         Pop $0       
     
118. !macroend               
     
119. 
     
120.         ;压缩档右键命令
     
121. !macro ASSOC_ARCHIVE EXT ARCHIVE_PLUGINS
     
122.         Push $0
     
123.        
     
124.         ReadRegStr $0 HKCR ".${EXT}" ""
     
125.         ${If} $0 == "" ;如果压缩文件没有关联则进行关联
     
126.                 ${StrCase} $0 '${EXT}' "U"
     
127.                 !insertmacro ASSOC "${EXT}" "${ARCHIVE_PLUGINS}"
     
128.                 WriteRegStr HKCR "ACDSee.${EXT}" "" "ACDSee 压缩文档($0)"
     
129.                 DeleteRegKey HKCR "ACDSee.${EXT}\shell"
     
130.         ${Else}
     
131.                 ReadRegStr $0 HKCR ".${EXT}" ""
     
132.                 WriteRegStr HKCR "$0\Shell\ACDSeeView" "" "用 ACDSee 察看"
     
133.                 WriteRegStr HKCR "$0\Shell\ACDSeeView\command" "" '"$INSTDIR\ACDSee.exe" "%1"'
     
134.                 WriteRegStr HKCR "ACDSee.File\Archive" "$0\Shell\ACDSeeView" ""
     
135.         ${EndIf}
     
136.        
     
137.         Pop $0
     
138. !macroend
     
139. 
     
140. !macro SelectIfSet SECTION
     
141.   Push $0
     
142.   Push $1
     
143.     SectionGetFlags "${SECTION}" $0
     
144.     IntOp $1 $0 & ${SF_SELECTED}
     
145.                 StrCmp $1 ${SF_SELECTED} +5
     
146.                 IntOp $0 $0 & ${SECTION_OFF}
     
147.     SectionSetFlags "${${SECTION}}" $0
     
148.                 SectionSetText "${${SECTION}}" ""
     
149.                 Goto +3
     
150.                 IntOp $0 $0 | ${SF_SELECTED}
     
151.     SectionSetFlags "${${SECTION}}" $0
     
152.   Pop $1
     
153.   Pop $0
     
154. !macroend
     
155. 
     
156. Section "主程序及标准插件" main
     
157.   SectionIn RO
     
158.         ;系统文件
     
159.         SetOverwrite off
     
160.         SetOutPath $SYSDIR
     
161.         File ".\include\Roboex32.dll"
     
162.         File ".\include\msvcr71.dll"
     
163.         SetOverwrite on
     
164.   Delete "$INSTDIR\install.log"
     
165.   LogSet on
     
166.         SetOutPath $INSTDIR
     
167.         File /r ".\include\main\*.*"
     
168.         SetOutPath "$INSTDIR\PlugIns"
     
169.         StrCpy $0 "$INSTDIR\PlugIns\IDE_ACDStd.apl"
     
170.         ClearErrors
     
171.         Delete $0
     
172.         ${If} ${Errors}
     
173.                 GetTempFileName $1
     
174.                 StrCpy $0 $1
     
175.         ${EndIf}
     
176.         File "/oname=$0" ".\include\plugins\IDE_ACDStd.apl"
     
177.         ${IfThen} $0 == $1 ${|} Rename /REBOOTOK $0 "$INSTDIR\PlugIns\IDE_ACDStd.apl" ${|}
     
178.         File ".\include\plugins\IDE_ACDStd.chm"
     
179.        
     
180.   WriteRegStr HKLM "SOFTWARE\ACD Systems\PlugInsV1" PIFolder "$INSTDIR\PlugIns"
     
181.         WriteRegBin HKLM "SOFTWARE\ACD Systems\ACDInTouch" "InTouchSettings" 01013d00000000000700000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000050000000
     
182.   WriteRegStr HKLM "SOFTWARE\ACD Systems\ACDSee" "" 3.1.1
     
183.         WriteRegStr HKLM "SOFTWARE\ACD Systems\ACDSeeCS" "" 3.1.1
     
184.   WriteRegBin HKLM "SOFTWARE\ACD Systems\ACDSeeCS" InTouchSettings 01535c4300000000
     
185.   WriteRegStr HKLM "SOFTWARE\ACD Systems\ACDSeeCS" SourceID 001
     
186.   WriteRegStr HKLM "SOFTWARE\ACD Systems\ACDSeeCS" InstallationDate HBNHFNEGGHCKKJDN091A4FB9
     
187.   WriteRegStr HKLM "SOFTWARE\ACD Systems\ACDSeeCS" InTouchConfigRemind CJPJNNEGGHCKKBBI08599FBA
     
188.   WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\ACDSee.exe" "" "$INSTDIR\ACDSee.exe"
     
189.   WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\ACDSee.exe" Path $INSTDIR
     
190.   WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\PELite.exe" "" "$INSTDIR\PELite.exe"
     
191.   WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\PELite.exe" Path $INSTDIR
     
192. 
     
193.   WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\Help" ACDSee.hlp $INSTDIR
     
194.        
     
195.   WriteRegDWORD HKCU "Software\ACD Systems\ACDSee\Tip" StartUp 1
     
196.         WriteRegBin HKCU "Software\ACD Systems\ACDSeeCS" RememberDir 01
     
197.        
     
198.         DeleteRegValue HKCR "SystemFileAssociations\image\ShellEx\ContextMenuHandlers\ShellImagePreview" ""
     
199.        
     
200.         ;注册信息
     
201.   ReadINIStr $0 "$PLUGINSDIR\ACDSee.ini" "Field 3" "State"
     
202.   WriteRegStr HKLM "SOFTWARE\ACD Systems\ACDSeeCS" LicenseNumber $0
     
203.   ReadINIStr $0 "$PLUGINSDIR\ACDSee.ini" "Field 7" "State"
     
204.         WriteRegStr HKLM "SOFTWARE\ACD Systems\ACDInTouch" UserName $0
     
205.   ReadINIStr $0 "$PLUGINSDIR\ACDSee.ini" "Field 9" "State"
     
206.         WriteRegStr HKLM "SOFTWARE\ACD Systems\ACDInTouch" CompanyName $0
     
207.   ReadINIStr $0 "$PLUGINSDIR\ACDSee.ini" "Field 11" "State"
     
208.         WriteRegStr HKLM "SOFTWARE\ACD Systems\ACDInTouch" UserEMail $0
     
209. SectionEnd       
     
210. 
     
211. Section "ACD 图像编辑器"
     
212.         File "/oname=$INSTDIR\PELite.exe" ".\include\PELite.exe"
     
213. SectionEnd       
     
214. 
     
215. Section PicaView
     
216.         SetOverwrite try
     
217.   File "/oname=$INSTDIR\PicaView.dll" ".\include\PicaView.dll"
     
218.         SetOverwrite on
     
219.        
     
220.   WriteRegBin HKCU "Software\ACD Systems\PicaView" CheckAllExtensions 00000000
     
221.   WriteRegBin HKCU "Software\ACD Systems\PicaView" PlaySounds 00
     
222.   WriteRegBin HKCU "Software\ACD Systems\PicaView" ShowFileSize 01000000
     
223.   WriteRegStr HKLM "Software\ACD Systems\PicaView" LicenseNumber 078723450172918441
     
224.        
     
225.   ReadINIStr $0 "$PLUGINSDIR\ACDSee.ini" "Field 7" "State"
     
226.   WriteRegStr HKLM "Software\ACD Systems\PicaView" UserName $0
     
227.        
     
228.   WriteRegStr HKLM "Software\ACD Systems\PicaView" PIFolder "$INSTDIR\PlugIns"
     
229.   WriteRegStr HKCR "CLSID\{68f32140-2ca3-11d0-acc1-444553540000}" "" "PicaView 外壳扩展"
     
230.   WriteRegStr HKCR "CLSID\{68f32140-2ca3-11d0-acc1-444553540000}\InProcServer32" "" "$INSTDIR\picaview.dll"
     
231.   WriteRegStr HKCR "CLSID\{68f32140-2ca3-11d0-acc1-444553540000}\InProcServer32" ThreadingModel Apartment
     
232.   WriteRegStr HKCR "PicaViewImage\Shell\Open\Command" "" 'rundll32 "$INSTDIR\picaview.dll,showimage %1"'
     
233.   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Shell Extensions\Approved" "{68f32140-2ca3-11d0-acc1-444553540000}" "PicaView"
     
234. SectionEnd
     
235. 
     
236. SubSection /e "扩展图形格式支持插件"
     
237.        
     
238. Section "图标和光标格式" ico
     
239.         File ".\include\plugins\ID_ICO.apl"
     
240. SectionEnd
     
241. 
     
242. Section "PhotoShop 图像" psd
     
243.         File ".\include\plugins\IDE_PSD.apl"
     
244. SectionEnd
     
245. 
     
246. Section "Paint Shop Pro 图像" psp
     
247.         File ".\include\plugins\ID_PSP.apl"
     
248. SectionEnd
     
249. 
     
250. Section "SGI 图像" sgi
     
251.         File ".\include\plugins\IDE_SGI.apl"
     
252. SectionEnd
     
253. 
     
254. Section "Kodak Photo 图像" pcd
     
255.         File ".\include\plugins\ID_PhotoCD.apl"
     
256. SectionEnd
     
257. 
     
258. Section "JPEG 2000" jp2
     
259.         File ".\include\plugins\IDE_JP2.apl"
     
260. SectionEnd
     
261. 
     
262. Section "数码相机 RAW 插件" raw
     
263.         File ".\include\plugins\ID_DCRaw.apl"
     
264. SectionEnd
     
265.        
     
266. Section
     
267. SectionEnd
     
268.        
     
269. Section "ICN 图标支持插件" icn
     
270.         File ".\include\plugins\ID_ICN.apl"
     
271. SectionEnd
     
272.        
     
273. SubSectionEnd
     
274. 
     
275. SubSection /e "功能扩展插件"
     
276.        
     
277. Section "无损 JPEG 旋转"
     
278.         File ".\include\plugins\CX_JPEGTrans.apl"
     
279. SectionEnd
     
280. 
     
281. Section "HTML 像册生成器" cx_html
     
282.         File ".\include\plugins\CX_HTML.apl"
     
283.         File ".\include\plugins\CX_HTML.chm"
     
284.         File ".\include\plugins\acdcp.dll"
     
285. SectionEnd
     
286. 
     
287. Section "图册实用工具" cx_csheet
     
288.         File ".\include\plugins\CX_ContactSheet.apl"
     
289.         File ".\include\plugins\CX_ContactSheet.chm"
     
290. SectionEnd
     
291. 
     
292. Section "调整层次"
     
293.         File ".\include\plugins\CX_AdjustLevels.apl"
     
294. SectionEnd
     
295. 
     
296. SubSectionEnd
     
297. 
     
298. SubSection /e "压缩文档支持插件"
     
299.        
     
300. Section ZIP zip
     
301.         File ".\include\plugins\AM_ZIP.apl"
     
302. SectionEnd
     
303.                
     
304. Section /o LHA lha
     
305.         File ".\include\plugins\AM_LHA.apl"
     
306. SectionEnd
     
307.                
     
308. Section /o RAR rar
     
309.         File ".\include\plugins\AM_RAR.apl"
     
310. SectionEnd
     
311.                
     
312. SubSectionEnd
     
313.        
     
314. Section "-post" post
     
315.         ;桌面快捷方式
     
316.   ReadINIStr $0 "$PLUGINSDIR\ACDSee.ini" "Field 13" "State"
     
317.   ${If} $0 == 1
     
318.                 CreateShortCut "$DESKTOP\ACDSee 3.1.lnk" "$INSTDIR\ACDSee.exe"
     
319.                 WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\ACDSee" Desktop 1
     
320.         ${EndIf}
     
321.   
     
322.         ;开始菜单
     
323.   ReadINIStr $0 "$PLUGINSDIR\ACDSee.ini" "Field 14" "State"
     
324.   ${If} $0 == 1
     
325.                 CreateDirectory "$SMPROGRAMS\ACDSee"
     
326.                 CreateShortCut "$SMPROGRAMS\ACDSee\ACDSee 3.1.lnk" "$INSTDIR\ACDSee.exe"
     
327.                 CreateShortCut "$SMPROGRAMS\ACDSee\卸载.lnk" "$INSTDIR\uninstall.exe"
     
328.                 CreateShortCut "$SMPROGRAMS\ACDSee\帮助文档.lnk" "$INSTDIR\ACDSee.hlp"
     
329.                 WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\ACDSee" StartMenu 1
     
330.         ${EndIf}
     
331.   
     
332.         ;快速启动
     
333.   ReadINIStr $0 "$PLUGINSDIR\ACDSee.ini" "Field 15" "State"
     
334.   ${If} $0 == 1
     
335.                 CreateShortCut "$QUICKLAUNCH\ACDSee 3.1.lnk" "$INSTDIR\ACDSee.exe"
     
336.                 WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\ACDSee" QuickLaunch 1
     
337.   ${EndIf}
     
338.        
     
339.         WriteUninstaller "$INSTDIR\uninstall.exe"
     
340.   LogSet off
     
341.        
     
342.         ;目录右键菜单
     
343.   ReadINIStr $0 "$PLUGINSDIR\ACDSee.ini" "Field 20" "State"
     
344.   ${If} $0 == 1
     
345.                 WriteRegStr HKCR "Directory\shell\ACDBrowse" "" "用 ACDSee 浏览"
     
346.                 WriteRegStr HKCR "Directory\shell\ACDBrowse\command" "" '"$INSTDIR\ACDSee.exe" "%1"'
     
347.                 WriteRegStr HKCR "Drive\shell\ACDBrowse" "" "用 ACDSee 浏览"
     
348.                 WriteRegStr HKCR "Drive\shell\ACDBrowse\command" "" '"$INSTDIR\ACDSee.exe" "%1"'
     
349.                 WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\ACDSee" ContextMenu 1
     
350.         ${EndIf}
     
351.        
     
352.   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\ACDSee" "DisplayName" "$(^NameDA)"
     
353.   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\ACDSee" UninstallString "$INSTDIR\uninstall.exe"
     
354.   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\ACDSee" DisplayIcon "$INSTDIR\ACDSee.exe"
     
355.         ${StrCase} $0 '$INSTDIR' "U"
     
356.   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\ACDSee" "InstallDir" $0
     
357.        
     
358. SectionEnd
     
359. 
     
360. Section "Association" association
     
361. SectionEnd
     
362. 
     
363. Section "Windows 和 OS/2 位图(bmp,dib,rle,wbmp)"
     
364.         !insertmacro ASSOC bmp "$INSTDIR\PlugIns\IDE_ACDStd.apl,1"
     
365.         !insertmacro ASSOC dib "$INSTDIR\PlugIns\IDE_ACDStd.apl,1"
     
366.         !insertmacro ASSOC rle "$INSTDIR\PlugIns\IDE_ACDStd.apl,1"
     
367.         !insertmacro ASSOC wbmp "$INSTDIR\PlugIns\IDE_ACDStd.apl,11"
     
368. SectionEnd
     
369. 
     
370. Section "增强图元文件格式(emf)"
     
371.         !insertmacro ASSOC emf "$INSTDIR\PlugIns\IDE_ACDStd.apl,2"
     
372. SectionEnd
     
373. 
     
374. Section "图形交换格式(gif)"
     
375.         !insertmacro ASSOC gif "$INSTDIR\PlugIns\IDE_ACDStd.apl,3"
     
376. SectionEnd
     
377. 
     
378. Section "标准 JPEG(jpg,jpeg,jpe,jif,jfif)"
     
379.         !insertmacro ASSOC jpg "$INSTDIR\PlugIns\IDE_ACDStd.apl,4"
     
380.         !insertmacro ASSOC jpeg "$INSTDIR\PlugIns\IDE_ACDStd.apl,4"
     
381.         !insertmacro ASSOC jpe "$INSTDIR\PlugIns\IDE_ACDStd.apl,4"
     
382.         !insertmacro ASSOC jif "$INSTDIR\PlugIns\IDE_ACDStd.apl,4"
     
383.         !insertmacro ASSOC jfif "$INSTDIR\PlugIns\IDE_ACDStd.apl,4"
     
384. SectionEnd
     
385. 
     
386. Section "ZSoft 出版画笔(pcx,dcx)"
     
387.         !insertmacro ASSOC pcx "$INSTDIR\PlugIns\IDE_ACDStd.apl,5"
     
388.         !insertmacro ASSOC dcx "$INSTDIR\PlugIns\IDE_ACDStd.apl,5"
     
389. SectionEnd
     
390. 
     
391. Section "便携网络图形(png)"
     
392.         !insertmacro ASSOC png "$INSTDIR\PlugIns\IDE_ACDStd.apl,6"
     
393. SectionEnd
     
394. 
     
395. Section "Targa TGA(tga)"
     
396.         !insertmacro ASSOC tga "$INSTDIR\PlugIns\IDE_ACDStd.apl,7"
     
397. SectionEnd
     
398. 
     
399. Section "Tag 图片文件格式(tif,tiff,xif)"
     
400.         !insertmacro ASSOC tif "$INSTDIR\PlugIns\IDE_ACDStd.apl,8"
     
401.         !insertmacro ASSOC tiff "$INSTDIR\PlugIns\IDE_ACDStd.apl,8"
     
402.         !insertmacro ASSOC xif "$INSTDIR\PlugIns\IDE_ACDStd.apl,8"
     
403. SectionEnd
     
404. 
     
405. Section "Windows 3.x 图元文件格式(wmf)"
     
406.         !insertmacro ASSOC wmf "$INSTDIR\PlugIns\IDE_ACDStd.apl,9"
     
407. SectionEnd
     
408. 
     
409. Section "Pegasus PIC 格式(pic)"
     
410.   SectionIn 1 2
     
411.         !insertmacro ASSOC pic "$INSTDIR\PlugIns\IDE_ACDStd.apl,10"
     
412. SectionEnd
     
413. 
     
414. Section "图标格式(ico,cur,ani)" ${ico}
     
415.         !insertmacro ASSOC ico "%1"
     
416.         !insertmacro ASSOC cur "%1"
     
417.         !insertmacro ASSOC ani "%1"
     
418. SectionEnd
     
419. 
     
420. Section "PhotoShop 图像格式(psd)" ${psd}
     
421.         !insertmacro ASSOC psd "$INSTDIR\PlugIns\IDE_PSD.apl,0"
     
422. SectionEnd
     
423. 
     
424. Section "Paint Shop Pro 图像格式(pspimage,psp,pspframe,pspshape,psptube,tub)" ${psp}
     
425.         !insertmacro ASSOC psp "$INSTDIR\PlugIns\ID_PSP.apl,0"
     
426.         !insertmacro ASSOC_TYPE pspimage PSP
     
427.         !insertmacro ASSOC_TYPE pspframe PSP
     
428.         !insertmacro ASSOC_TYPE pspshape PSP
     
429.         !insertmacro ASSOC_TYPE psptube PSP
     
430.         !insertmacro ASSOC_TYPE tub PSP
     
431. SectionEnd
     
432. 
     
433. Section "SGI 图像格式(sgi)" ${sgi}
     
434.         !insertmacro ASSOC sgi "$INSTDIR\PlugIns\IDE_SGI.apl,0"
     
435. SectionEnd
     
436. 
     
437. Section "Kodak Photo 图像格式(pcd)" ${pcd}
     
438.         !insertmacro ASSOC pcd "$INSTDIR\PlugIns\ID_PhotoCD.apl,0"
     
439. SectionEnd
     
440. 
     
441. Section "JPEG 2000(jp2)" ${jp2}
     
442.         !insertmacro ASSOC jp2 "$INSTDIR\PlugIns\IDE_JP2.apl,0"
     
443.         !insertmacro ASSOC jpc "$INSTDIR\PlugIns\IDE_JP2.apl,0"
     
444. SectionEnd
     
445. 
     
446. Section "数码相机 RAW 格式图像" ${raw}
     
447.         !insertmacro ASSOC raw "$INSTDIR\PlugIns\ID_DCRaw.apl,0"
     
448.         !insertmacro ASSOC cr2 "$INSTDIR\PlugIns\ID_DCRaw.apl,1"
     
449.         !insertmacro ASSOC crw "$INSTDIR\PlugIns\ID_DCRaw.apl,2"
     
450.         !insertmacro ASSOC dcr "$INSTDIR\PlugIns\ID_DCRaw.apl,3"
     
451.         !insertmacro ASSOC mrw "$INSTDIR\PlugIns\ID_DCRaw.apl,4"
     
452.         !insertmacro ASSOC nef "$INSTDIR\PlugIns\ID_DCRaw.apl,5"
     
453.         !insertmacro ASSOC orf "$INSTDIR\PlugIns\ID_DCRaw.apl,6"
     
454.         !insertmacro ASSOC pef "$INSTDIR\PlugIns\ID_DCRaw.apl,7"
     
455.         !insertmacro ASSOC raf "$INSTDIR\PlugIns\ID_DCRaw.apl,8"
     
456.         !insertmacro ASSOC tiff "$INSTDIR\PlugIns\ID_DCRaw.apl,9"
     
457.         !insertmacro ASSOC x3f "$INSTDIR\PlugIns\ID_DCRaw.apl,10"
     
458. SectionEnd
     
459. 
     
460. Section "ICN 图标(icn)" ${icn}
     
461.         !insertmacro ASSOC icn "$INSTDIR\PlugIns\ID_ICN.apl,0"
     
462. SectionEnd
     
463. 
     
464. Section "ZIP (右键菜单)" ${zip}
     
465.         !insertmacro ASSOC_ARCHIVE zip "$INSTDIR\PlugIns\AM_ZIP.apl"
     
466. SectionEnd
     
467.                
     
468. Section "LHA (右键菜单)" ${lha}
     
469.         !insertmacro ASSOC_ARCHIVE lha "$INSTDIR\PlugIns\AM_LHA.apl"
     
470. SectionEnd
     
471.                
     
472. Section "RAR (右键菜单)" ${rar}
     
473.         !insertmacro ASSOC_ARCHIVE rar "$INSTDIR\PlugIns\AM_RAR.apl"
     
474. SectionEnd
     
475.                
     
476. Section "End" end
     
477. SectionEnd
     
478. 
     
479. !ifdef DEBUG
     
480. Section
     
481.         Push "$PLUGINSDIR\debug.txt"
     
482.         Call DumpLog
     
483.         ExecShell open "$PLUGINSDIR\debug.txt" "" SW_SHOWMAXIMIZED
     
484.         Sleep 1000
     
485. SectionEnd
     
486. 
     
487. Function DumpLog
     
488.   Exch $R5
     
489.   Push $R0
     
490.   Push $R1
     
491.   Push $R2
     
492.   Push $R3
     
493.   Push $R4
     
494.   Push $R6
     
495. 
     
496.   FindWindow $R0 "#32770" "" $HWNDPARENT
     
497.   GetDlgItem $R0 $R0 1016
     
498.   StrCmp $R0 0 exit
     
499.   FileOpen $R5 $R5 "a"
     
500.         FileSeek $R5 0 END
     
501.   StrCmp $R5 "" exit
     
502.     SendMessage $R0 0x1004 0 0 $R6
     
503.     System::Alloc ${NSIS_MAX_STRLEN}
     
504.     Pop $R3
     
505.     StrCpy $R2 0
     
506.     System::Call "*(i, i, i, i, i, i, i, i, i) i \
     
507.       (0, 0, 0, 0, 0, R3, ${NSIS_MAX_STRLEN}) .R1"
     
508.     loop: StrCmp $R2 $R6 done
     
509.       System::Call "User32::SendMessageA(i, i, i, i) i \
     
510.         ($R0, 0x102D, $R2, R1)"
     
511.       System::Call "*$R3(&t${NSIS_MAX_STRLEN} .R4)"
     
512.       FileWrite $R5 "$R4"
     
513.       FileWriteByte $R5 13
     
514.       FileWriteByte $R5 10
     
515.       IntOp $R2 $R2 + 1
     
516.       Goto loop
     
517.     done:
     
518.       FileClose $R5
     
519.       System::Free $R1
     
520.       System::Free $R3
     
521.   exit:
     
522.     Pop $R6
     
523.     Pop $R4
     
524.     Pop $R3
     
525.     Pop $R2
     
526.     Pop $R1
     
527.     Pop $R0
     
528.     Pop $R5
     
529. FunctionEnd
     
530. !endif
     
531. 
     
532. ;**********************************************************************
     
533. 
     
534. Function .onInit
     
535.   InitPluginsDir
     
536.         File "/oname=$PLUGINSDIR\acdsee.ini" ".\resource\acdsee.ini"
     
537.         File "/oname=$PLUGINSDIR\gaydata.ini" ".\resource\gaydata.ini"
     
538.        
     
539.         System::Call "advapi32::GetUserName(t .r0, *i ${NSIS_MAX_STRLEN} r1) i.r2"
     
540.   WriteINIStr "$PLUGINSDIR\acdsee.ini" "Field 7" "State" $0
     
541.        
     
542.         ReadRegStr $0 HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\ACDSee" "InstallDir"
     
543.         ${If} $0 != ""
     
544.                 ReadRegStr $0 HKLM "SOFTWARE\ACD Systems\ACDSeeCS" LicenseNumber
     
545.                 WriteINIStr "$PLUGINSDIR\acdsee.ini" "Field 3" "State" $0
     
546.                 ReadRegStr $0 HKLM "SOFTWARE\ACD Systems\ACDInTouch" UserName
     
547.                 WriteINIStr "$PLUGINSDIR\acdsee.ini" "Field 7" "State" $0
     
548.                 ReadRegStr $0 HKLM "SOFTWARE\ACD Systems\ACDInTouch" CompanyName
     
549.                 WriteINIStr "$PLUGINSDIR\ACDSee.ini" "Field 9" "State" $0
     
550.                 ReadRegStr $0 HKLM "SOFTWARE\ACD Systems\ACDInTouch" UserEMail
     
551.                 WriteINIStr "$PLUGINSDIR\acdsee.ini" "Field 11" "State" $0
     
552.        
     
553.                 ReadRegStr $0 HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\ACDSee" Desktop
     
554.                 WriteINIStr "$PLUGINSDIR\acdsee.ini" "Field 13" "State" $0
     
555.                 ReadRegStr $0 HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\ACDSee" StartMenu
     
556.                 WriteINIStr "$PLUGINSDIR\acdsee.ini" "Field 14" "State" $0
     
557.                 ReadRegStr $0 HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\ACDSee" QuickLaunch
     
558.                 WriteINIStr "$PLUGINSDIR\acdsee.ini" "Field 15" "State" $0
     
559.                 ReadRegStr $0 HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\ACDSee" ContextMenu
     
560.                 WriteINIStr "$PLUGINSDIR\acdsee.ini" "Field 20" "State" $0
     
561.         ${EndIf}
     
562. FunctionEnd
     
563. 
     
564. Function CheckDependence
     
565.         !insertmacro SelectIfSet ${ico}
     
566.         !insertmacro SelectIfSet ${psd}
     
567.         !insertmacro SelectIfSet ${psp}
     
568.         !insertmacro SelectIfSet ${sgi}
     
569.         !insertmacro SelectIfSet ${pcd}
     
570.         !insertmacro SelectIfSet ${jp2}
     
571.         !insertmacro SelectIfSet ${icn}
     
572.         !insertmacro SelectIfSet ${zip}
     
573.         !insertmacro SelectIfSet ${lha}
     
574.         !insertmacro SelectIfSet ${rar}
     
575.         !insertmacro SelectIfSet ${raw}
     
576. FunctionEnd
     
577. 
     
578. Function ComponentPre
     
579.         Push $0
     
580.         Push $1
     
581.        
     
582.         FindWindow $0 "#32770" "" $HWNDPARENT
     
583.   GetDlgItem $1 $0 1017
     
584.         ShowWindow $1 ${SW_HIDE}
     
585.        
     
586.         Call ResetSectionText
     
587.        
     
588.         ;隐藏 Asscoiations
     
589.         ${For} $0 ${association} ${end}
     
590.                 SectionSetText $0 ""
     
591.         ${Next}
     
592.        
     
593.         ;HTML 像册生成器 和 图册实用工具 在 2000、98 下无法使用
     
594.         ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion" CurrentVersion
     
595.         ${If} $0 == ""
     
596.         ${OrIf} $0 == "5.0"
     
597.                 !insertmacro UnselectSection ${cx_html}
     
598.                 !insertmacro UnselectSection ${cx_csheet}
     
599.                 SectionSetText ${cx_html} ""
     
600.                 SectionSetText ${cx_csheet} ""
     
601.         ${EndIf}
     
602.        
     
603.         Pop $1
     
604.         Pop $0
     
605. FunctionEnd
     
606. 
     
607. Function ComponentShow
     
608.         Push $0
     
609.         Push $1
     
610.                 ${For} $1 ${main} ${post}
     
611.                         ReadINIStr $0 "$PLUGINSDIR\gaydata.ini" "secnames" "sec$1"
     
612.                         SectionSetText $1 $0
     
613.                 ${Next}
     
614.         Pop $1
     
615.         Pop $0
     
616. FunctionEnd
     
617. 
     
618. Function AsscoiationPre
     
619.         Push $0
     
620.         Push $1
     
621.                 Call ResetSectionText
     
622.                 ;隐藏 Components
     
623.                 ${For} $0 ${main} ${post}
     
624.                         SectionSetText $0 ""
     
625.                 ${Next}
     
626.                 Call CheckDependence
     
627.         Pop $1
     
628.         Pop $0
     
629. FunctionEnd
     
630. 
     
631. Function AsscoiationShow
     
632.         Push $0
     
633.         Push $1
     
634.                 ${For} $1 ${association} ${end}
     
635.                         ReadINIStr $0 "$PLUGINSDIR\gaydata.ini" "secnames" "sec$1"
     
636.                         SectionSetText $1 $0
     
637.                 ${Next}
     
638.         Pop $1
     
639.         Pop $0
     
640. FunctionEnd
     
641. 
     
642. Function ResetSectionText
     
643.         Push $R0
     
644.         Push $R1
     
645.                 ${For} $R1 ${main} ${end}
     
646.                         ReadINIStr $R0 "$PLUGINSDIR\gaydata.ini" "secnames" "sec$R1"
     
647.                         ${If} $R0 == ""
     
648.                                 SectionSetText $R1 ""
     
649.                         ${Else}
     
650.                                 SectionSetText $R1 " "
     
651.                         ${EndIf}
     
652.                 ${Next}
     
653.         Pop $R1
     
654.         Pop $R0
     
655. FunctionEnd
     
656. 
     
657. Function SetCustom
     
658.   InstallOptions::initDialog /NOUNLOAD $PLUGINSDIR\acdsee.ini
     
659.   !insertmacro MUI_HEADER_TEXT "个性化设置" "请输入你需要定制的个人信息"
     
660.         InstallOptions::show
     
661. FunctionEnd       
     
662. 
     
663. Function ChageFONT
     
664.         GetDlgItem $0 $MUI_HWND 1201
     
665.         CreateFont $1 "Tahoma" "11" "700"
     
666.         SendMessage $0 ${WM_SETFONT} $1 0
     
667. FunctionEnd       
     
668. 
     
669. ;******************************************************
     
670. ; 卸载段
     
671. ;******************************************************
     
672. 
     
673. 
     
674. Section Uninstall
     
675.         Call un.Restore
     
676.         FindWindow $0 "Afx:400000:8"
     
677.         SendMessage $0 ${WM_CLOSE} 0 0
     
678.         Call un.DelReg
     
679.        
     
680.         Push "$INSTDIR\install.log"
     
681.         Call un.DelFileByLog
     
682.         Push "$INSTDIR\install.log"
     
683.         Call un.RMDirByLog
     
684.         Delete "$INSTDIR\install.log"
     
685.         RMDir "$INSTDIR"
     
686.        
     
687.   System::Call 'shell32.dll::SHChangeNotify(l, l, i, i) v (0x08000000, 0, 0, 0)'
     
688.        
     
689.         ${If} ${RebootFlag}
     
690.                 MessageBox MB_YESNO|MB_ICONEXCLAMATION "某个文件需要重启后才能删除，现在重新启动吗？" IDNO +2
     
691.                 Reboot
     
692.         ${ElseIf} ${FileExists} $INSTDIR
     
693.                 MessageBox MB_OK|MB_ICONINFORMATION "某些文件并不是安装程序产生的，因此需要你手动删除"
     
694.                 ExecShell open $INSTDIR SW_SHOWMAXIMIZED
     
695.         ${EndIf}
     
696. SectionEnd
     
697. 
     
698. Function un.Restore
     
699.   Push $R0
     
700.   Push $R1
     
701.   Push $R2
     
702.   Push $R3
     
703.        
     
704.   StrCpy $R0 0
     
705.   loop:
     
706.     EnumRegValue $R1 HKCR "ACDSee.FILE" $R0
     
707.     ReadRegStr $R3 HKCR ".$R1\UndoClass" ""
     
708.                
     
709.     StrCmp $R1 "" loop_quit
     
710.                
     
711.     StrCmp $R3 "" 0 restore                ;如果备份的是空值则直接删除
     
712.     DeleteRegKey HKCR ".$R1"
     
713.                 DeleteRegKey HKCR "ACDSee.$R1"
     
714.     DetailPrint ".$R1 文件关联已被移除"
     
715.     Goto cont_restore
     
716.                
     
717.     restore:
     
718.     ReadRegStr $R2 HKCR ".$R1" ""
     
719.     StrCpy $R2 $R2 7
     
720.     StrCmp $R2 "ACDSee." 0 no_restore
     
721.     WriteRegStr HKCR ".$R1" "" "$R3"
     
722.                 DeleteRegKey HKCR "ACDSee.$R1"
     
723.     DetailPrint ".$R1 文件关联已被恢复"
     
724.     Goto cont_restore
     
725.                
     
726.     no_restore:
     
727.     DetailPrint ".$R1 未被关联到 ACDSee，略过"
     
728.                
     
729.     cont_restore:
     
730.     IntOp $R0 $R0 + 1
     
731.     Goto loop
     
732.   loop_quit:
     
733.        
     
734.   StrCpy $R0 0 ;清除关联的压缩文档
     
735.   loop2:
     
736.     EnumRegValue $R1 HKCR ACDSee.File\Archive $R0
     
737.                 StrCmp $R1 "" loop2_quit
     
738.                 EnumRegKey $R2 HKCR $R1 0
     
739.                 StrCmp $R2 "" +2
     
740.                 DeleteRegKey HKCR $R1
     
741.     IntOp $R0 $R0 + 1
     
742.     Goto loop2
     
743.   loop2_quit:
     
744.        
     
745.         DeleteRegKey HKCR .apl
     
746.         DeleteRegKey HKCR ACD.PlugIn
     
747.         DeleteRegKey HKCR ACDSee.FILE
     
748.        
     
749.   Pop $R3
     
750.   Pop $R2
     
751.   Pop $R1
     
752.   Pop $R0
     
753. FunctionEnd
     
754. 
     
755. Function un.DelFileByLog
     
756.         Exch $R0
     
757.         Push $R1
     
758.         Push $R2
     
759.         Push $R3
     
760.        
     
761.         FileOpen $R0 $R0 r
     
762.         ${Do}
     
763.           FileRead $R0 $R1
     
764.                 StrCpy $R1 $R1 -2
     
765.                 StrCpy $R2 $R1 11
     
766.                 StrCpy $R3 $R1 20
     
767.                 ${If} $R2 == "File: wrote"
     
768.                 ${OrIf} $R2 == "File: skipp"
     
769.                 ${OrIf} $R3 == "CreateShortCut: out:"
     
770.                 ${OrIf} $R3 == "created uninstaller:"
     
771.                         Push $R1
     
772.                         Push '"'
     
773.                         Call un.StrLoc
     
774.                         Pop $R2
     
775.                         ${If} $R2 != ""
     
776.                                 IntOp $R2 $R2 + 1
     
777.                                 StrCpy $R3 $R1 "" $R2
     
778.                                 Push $R3
     
779.                                 Push '"'
     
780.                                 Call un.StrLoc
     
781.                                 Pop $R2
     
782.                                 ${If} $R2 != ""
     
783.                                         StrCpy $R3 $R3 $R2
     
784.                                         Delete /REBOOTOK $R3
     
785.                                 ${EndIf}
     
786.                         ${EndIf}
     
787.                 ${EndIf}
     
788.                 StrCpy $R2 $R1 7
     
789.                 ${If} $R2 == "Rename:"
     
790.                         Push $R1
     
791.                         Push '->'
     
792.                         Call un.StrLoc
     
793.                         Pop $R2
     
794.                         ${If} $R2 != ""
     
795.                                 IntOp $R2 $R2 + 2
     
796.                                 StrCpy $R3 $R1 "" $R2
     
797.                                 Delete /REBOOTOK $R3
     
798.                         ${EndIf}
     
799.                 ${EndIf}
     
800.         ${LoopUntil} $R1 == ""
     
801.         FileClose $R0
     
802.                
     
803.         Pop $R3
     
804.         Pop $R2
     
805.         Pop $R1
     
806.         Pop $R0
     
807. FunctionEnd
     
808. 
     
809. Function un.RMDirByLog
     
810.         Exch $R0
     
811.         Push $R1
     
812.         Push $R2
     
813.         Push $R3
     
814.         Push $R4
     
815.        
     
816.         FileOpen $R0 $R0 r
     
817.         FileSeek $R0 16 END $R1
     
818.         ${Do}
     
819.                 FileSeek $R0 -3 CUR $R1
     
820.                 FileReadByte $R0 $R2
     
821.                 FileReadByte $R0 $R3
     
822.                 ${If} "$R2$R3" == "1310"
     
823.                         FileRead $R0 $R2
     
824.                         FileSeek $R0 $R1
     
825.                         StrCpy $R3 $R2 16
     
826.                         ${If} $R3 == "CreateDirectory:"
     
827.                                 Push $R2
     
828.                                 Push '"'
     
829.                                 Call un.StrLoc
     
830.                                 Pop $R3
     
831.                                 ${If} $R3 != ""
     
832.                                         IntOp $R3 $R3 + 1
     
833.                                         StrCpy $R3 $R2 "" $R3
     
834.                                         Push $R3
     
835.                                         Push '"'
     
836.                                         Call un.StrLoc
     
837.                                         Pop $R2
     
838.                                         ${If} $R2 != ""
     
839.                                                 StrCpy $R2 $R3 $R2
     
840.                                                 ; ----------------------特殊目录则跳过
     
841.                                                 ${If} $R2 != $PLUGINSDIR
     
842.                                                 ${AndIf} $R2 != $PROGRAMFILES
     
843.                                                 ${AndIf} $R2 != $COMMONFILES
     
844.                                                 ${AndIf} $R2 != $DESKTOP
     
845.                                                 ${AndIf} $R2 != $STARTMENU
     
846.                                                 ${AndIf} $R2 != $SMPROGRAMS
     
847.                                                 ${AndIf} $R2 != $SMSTARTUP
     
848.                                                 ${AndIf} $R2 != $QUICKLAUNCH
     
849.                                                 ${AndIf} $R2 != $FAVORITES
     
850.                                                         RMDir $R2 ;如果是空目录则删除
     
851.                                                 ${EndIf}
     
852.                                                 ; ----------------------
     
853.                                         ${EndIf}
     
854.                                 ${EndIf}
     
855.                         ${EndIf}
     
856.                 ${EndIf}
     
857.         ${LoopUntil} $R1 < 10
     
858.         FileClose $R0
     
859.        
     
860.         Pop $R4
     
861.         Pop $R3
     
862.         Pop $R2
     
863.         Pop $R1
     
864.         Pop $R0
     
865. FunctionEnd
     
866. 
     
867. Function un.StrLoc
     
868.         Exch $R0 ;Str to search for
     
869.         Exch
     
870.         Exch $R1 ;string
     
871.         Push $R2 ;len of Str to search for
     
872.         Push $R3 ;len of string
     
873.         Push $R4
     
874.         Push $R5
     
875.                 StrLen $R2 $R0
     
876.                 StrLen $R3 $R1
     
877.                 ${Do}
     
878.                         StrCpy $R5 $R1 $R2 $R4
     
879.                         ${If} $R5 == $R0
     
880.                         ${OrIf} $R4 = $R3
     
881.                                 ${ExitDo}
     
882.                         ${EndIf}
     
883.                         IntOp $R4 $R4 + 1
     
884.                 ${Loop}
     
885.                 ${If} $R4 = $R3
     
886.                         StrCpy $R0 ""
     
887.                 ${Else}
     
888.                         StrCpy $R0 $R4
     
889.                 ${EndIf}       
     
890.         Pop $R5
     
891.         Pop $R4
     
892.         Pop $R3
     
893.         Pop $R2
     
894.         Pop $R1
     
895.         Exch $R0
     
896. FunctionEnd       
     
897. 
     
898. Function un.DelReg
     
899.   ReadRegStr $0 HKCR "CLSID\{68f32140-2ca3-11d0-acc1-444553540000}" ""
     
900.   ${If} $0 != ""
     
901.                 DeleteRegKey HKCU "Software\ACD Systems\PicaView"
     
902.                 DeleteRegKey HKLM "Software\ACD Systems\PicaView"
     
903.                 DeleteRegKey HKCR "CLSID\{68f32140-2ca3-11d0-acc1-444553540000}"
     
904.                 DeleteRegKey HKCR "PicaViewImage"
     
905.                 DeleteRegValue HKCR "*\shellex\ContextMenuHandlers\PicaView" ""
     
906.                 DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Shell Extensions\Approved" "{68f32140-2ca3-11d0-acc1-444553540000}"
     
907.   ${EndIf}
     
908.        
     
909.         DeleteRegValue HKLM "SOFTWARE\ACD Systems\ACDSee" InstallationDate
     
910.         DeleteRegValue HKLM "SOFTWARE\ACD Systems\ACDSee" InTouchSettings
     
911.         DeleteRegValue HKLM "SOFTWARE\ACD Systems\ACDSee" LicenseNumber
     
912.         DeleteRegValue HKLM "SOFTWARE\ACD Systems\ACDSee" ServerList
     
913.         DeleteRegValue HKLM "SOFTWARE\ACD Systems\ACDSee" UsageCount
     
914.         DeleteRegKey /ifempty HKLM "SOFTWARE\ACD Systems\ACDSee"
     
915.         DeleteRegKey /ifempty HKLM "SOFTWARE\ACD Systems"
     
916.         DeleteRegKey HKCU "SOFTWARE\ACD Systems\PlugInsV1"
     
917.         DeleteRegKey HKCU "SOFTWARE\ACD Systems\PicaView"
     
918.         DeleteRegKey HKLM "SOFTWARE\ACD Systems\PlugInsV1"
     
919.         DeleteRegKey HKLM "SOFTWARE\ACD Systems\PicaView"
     
920.         DeleteRegKey HKLM "SOFTWARE\ACD Systems\ACDInTouch"
     
921.         DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\ACDSee"
     
922. FunctionEnd       
     

复制代码